当前位置: 首页>编程语言>正文

expect脚本编程简明教程

概述

expect是Unix系统中用来进行自动化控制和测试的软件工具,由Don Libes制作,作为Tcl脚本语言的一个扩展,应用在交互式软件中如telnet,ftp,Passwd,fsck,rlogin,tip,ssh等等。

该工具利用Unix伪终端包装其子进程,允许任意程序通过终端接入进行自动化控制;也可利用Tk工具,将交互程序包装在X11的图形用户界面中。

我们通过Shell可以实现简单的控制流功能,如:循环、判断等。但是对于需要交互的场合则必须通过人工来干预,比如普通用户使用sudo命令时就需要我们手动输入密码;expect就是能够完成这种自动交互任务,而无需人的干预。Expect的作者Don Libes在1990年开始编写Expect时对Expect做有如下定义:Expect是一个用来实现自动交互功能的软件套件(Expect [is a] software suite for automating interactive tools)。系统管理员可以使用它创建用来实现对命令或程序提供输入的脚本:一般来说这些输入都需要手工输入(比如之前提到的执行sudo程序期望用户从终端输入用户密码)进行的,Expect则可以根据程序的提示模拟标准输入给程序提供信息来实现交互程序执行。甚至可以实现简单的BBS聊天机器人。

Expect是不断发展的,随着时间的流逝,其功能越来越强大,已经成为系统管理员的的一个强大助手。Expect需要Tcl编程语言的支持,要在系统上运行Expect必须首先安装Tcl。

工作原理

从最简单的层次来说,Expect的工作方式象一个通用化的Chat脚本工具。Chat脚本最早用于UUCP网络内,以用来实现计算机之间需要建立连接时进行特定的登录会话的自动化.
Chat脚本由一系列expect-send对组成;
expect等待输出特定的字符,通常是一个提示符,如果等到了就使用send发送特定的响应,例如下面我们使用expect-send对来模拟一遍用户名和密码的交互式输入:

	expect "Login:"
	send "somebody\n"

	# expect等待"Password:",使用send回应111111
	expect "Password:"
	send "111111\n"

expect等待标准输出中出现Login:字符串,如果等到了Login:字符串,就使用send somebody\n(其中\n用于模拟敲回车);然后继续等待标准输出中出现Password:字符串,如果等到了Password:字符串,就使用111111\n(其中\n用于模拟敲回车)。
上述几条语句描述出了Expect最简单的脚本操作模式。

应用

自动登陆ssh服务器

使用expect实现自动登录的脚本,本文用一个最短的例子说明脚本的原理。

	#!/usr/bin/expect
	set timeout 30
	spawn ssh test@127.0.0.1
	expect "password:"
	send "123456\n"
	interact

其中,

  1. #!/usr/bin/expect
    这一行告诉操作系统脚本里的代码使用那一个shell来执行。这里的expect其实和linux下的bash、windows下的cmd是一类东西。
    注意:这一行需要在脚本的第一行。
  2. set timeout 30
    设置超时时间,单位是秒;expect超时等待的时间。默认timeout为10s。
  3. spawn ssh test@127.0.0.1
    spawn是进入expect环境后才可以执行的expect内部命令,如果没有装expect或者直接在shell下执行是找不到spawn命令的。这个就好比cd是shell的内建命令,离开shell,就无法执行cd一样。 它主要的功能是给ssh运行进程加个壳,用来传递交互指令。
  4. [expect "password:"]
    这里的expect也是Expect脚本语言的一个内部命令。在shell下输入expect,会进入expect的工作界面,这个expect是一个shell命令,而expect "password:" 中的expect只是一个跟expect脚本名同名的一个内建命令。这个命令的意思是判断上次输出结果里是否包含password:的字符串,如果有则立即返回,向下执行;否则就一直等待,直到超时时间到,就是2里的30秒。
  5. send "123456\n"
    这里就是执行交互动作,与手工输入密码的动作等效。效果上跟用户手动在终端上输入123456之后敲一个回车一样。
  6. interact
    执行完成上述命令后保持在交互状态,此时Expect会把控制权交给控制台,这个时候就变回手工操作,Expect已经执行完成。如果没有这一句登录完成后会立刻退出,而不是留在远程终端上。如果你只是登录过去执行一段命令就退出,可将其改为expect eof
    该脚本执行现象如下:
	gyl@gyl:~$ ./test.exp 
	spawn ssh test@127.0.0.1
	test@127.0.0.1's password: 
	Linux gyl 2.6.32-46-generic #108-Ubuntu SMP Thu Apr 11 15:55:01 UTC 2013 i686 GNU/Linux
	Ubuntu 10.04.4 LTS

	Welcome to Ubuntu!
	 * Documentation:  https://help.ubuntu.com/

	New release 'precise' available.
	Run 'do-release-upgrade' to upgrade to it.

	Last login: Sat May 11 01:08:19 2013 from localhost
	$

封装scp语句实现上传下载的自动交互

	#!/usr/bin/expect

	#
	#auto down/up files from/to server over scp.protocol
	#Usage:
	# autoscp -down srcpath (the same as autoscp -down srcpath .)
	# autoscp -down srcpath dstpath (dstpath is based on $pwd)
	# autoscp -up srcpath (the same as autoscp -up srcpath ~)
	# autoscp -up srcpath dstpath (dstpath is based on ~ on the server)
	#

	set timeout 100
	set cmd [lindex $argv0]
	set option [lindex $argv 0]
	set srcpath [lindex $argv 1]
	set dstpath [lindex $argv 2]

	#parse command number
	switch -- $argc {
	    2 {
		set dstpath .
	    }
	    3 {
	    }
	    default {
		send_user "Usage:$cmd option srcpath \[dstpath\]\n"
		exit
	    }
	}

	#parse command and do it.
	if {$option=="-down"} {
	    spawn scp -r gyl@127.0.0.1:/home/gyl/$srcpath $dstpath
	} else {
	    if {$option=="-up"} {
		spawn scp -r $srcpath gyl@127.0.0.1:/home/gyl/$dstpath
	    } else {
		send_user "bad arg:\"$option\"\n"
		exit
	    }
	}

	#autofill infomation
	expect "password:"
	send "123456\n"

	#exit
	expect eof

该脚本仿照C语言的命令行参数,用到switch-case语句,if-else语句,功能算是比较全面了。
该脚本规定了有4种使用方法,不符合使用要求时给出相应提示。其中上传和下载每种操作含有加dstpath和不含dstpath,共4种;

	autoscp -down srcpath dstpath #srcpath基于服务器用户主目录,dstpath基于本地当前目录
	autoscp -down srcpath        #等价于autoscp -down srcpath .
	autoscp -up srcpath dstpath    #srcpath基于本地当前目录,dstpath基于服务器用户主目录
	autoscp -up srcpath        #等价于autoscp -up srcpath ~

NOTE:因为该脚本使用scp的上传下载功能,当操作大文件时,耗时较久,如果timeout值过小,超时时间一到,数据传输就会终止,程序退出。因此timeout值应该根据文件大小做适当调整。

参考资料

  1. Expect手册中文版
  2. Linux自动登录系统执行命令<2>expect
  3. Shell_scp expect实现
  4. linux shell+expect:批量scp脚本工具

https://www.xamrdz.com/lan/5kv1848792.html

相关文章: